
 1000  *SAVE MLI.ERROR.PLUS
 1010  *--------------------------------
 1020  CMDADR .EQ $BF9C
 1030  *--------------------------------
 1040  PRBYTE .EQ $FDDA
 1050  COUT   .EQ $FDED
 1060  *--------------------------------
 1070  MLI.ERROR.PLUS
 1080         STA ERRCOD   SAVE ERROR NUMBER
 1090         LDY CMDADR+1
 1100         LDA CMDADR   SUBTRACT 6 FROM ADDRESS
 1110         SEC
 1120         SBC #6
 1130         STA CALADR+1      CALL ADDR LO
 1140         BCS .1
 1150         DEY
 1160  .1     STY CALADR+2      CALL ADDR HI
 1170  *--------------------------------
 1180         LDY #2
 1190         LDX #3       COPY OPCODE & PARMS ADDR
 1200  CALADR LDA $9999,X       (ADDRESS FILLED IN)
 1210         INX
 1220         STA PARMADR.H,Y
 1230         DEY
 1240         BPL CALADR   ...UNTIL Y=-1
 1250  *--------------------------------
 1260         BMI .2       ...ALWAYS
 1270  .1     JSR COUT
 1280  .2     INY
 1290         LDA QERR,Y
 1300         BMI .1       ...ASCII CHAR
 1310         BNE .3       ...DATA BYTE
 1320         RTS          ...END
 1330  .3     TAX          USE AS INDEX
 1340         LDA MLI.ERROR.PLUS,X
 1350         JSR PRBYTE
 1360         JMP .2       NEXT CHAR
 1370  *--------------------------------
 1380  ERRCOD     .BS 1
 1390  PARMADR.H  .BS 1
 1400  PARMADR.L  .BS 1
 1410  OPCODE     .BS 1
 1420  *--------------------------------
 1430  QERR   .HS 8D
 1440         .AS -/MLI ERROR $/
 1450         .DA #ERRCOD-MLI.ERROR.PLUS
 1460         .AS -/ AT $/
 1470         .DA #CALADR-MLI.ERROR.PLUS+2
 1480         .DA #CALADR-MLI.ERROR.PLUS+1
 1490         .AS -/ (/
 1500         .DA #OPCODE-MLI.ERROR.PLUS
 1510         .AS -/./
 1520         .DA #PARMADR.H-MLI.ERROR.PLUS
 1530         .DA #PARMADR.L-MLI.ERROR.PLUS
 1540         .AS -/)/
 1550         .HS 8D.00
 1560  *--------------------------------
 1570         .LIST OFF

